您好，SH。您知道，在我们撰写此专栏时，第一轮 NCAA 男子篮球联赛正进行得如火如荼。不过别担心：尽管本年度的首轮比赛都将通过 Internet 实况广播，但您尽可放心，脚本专家仍在尽心竭力地工作且毫不分神地对待您的问题。

哦，帮帮忙，裁判：您持有哨子，您不妨使用它吧！

很抱歉。噢，穿过大厅的那个人似乎把 CD 播放机的音量开的太大了。喂，您能小点声吗？我们中的某些人要在这工作。

您能相信某些人的勇气吗？边工作边看大学篮球赛；真不害臊。

现在让我们来看一下，我们正在谈论 Brandon Roy（本赛季年度最佳运动员），他在昨晚华盛顿大学爱斯基摩犬队击败犹他州立大学队的比赛中个人独得 28 分。正如 Brandon 在赛后记者招待会中所言，是的，SH，您能够通过脚本获得已安装设备驱动程序的列表、版本号及其日期。事实上，您可以使用与此相似的脚本以获得这些信息：

strComputer = "."

Set objWMIService = GetObject("winmgmts://" & strComputer & "/root/cimv2")



Set colItems = objWMIService.ExecQuery("Select * from Win32_PnPSignedDriver")



For Each objItem in colItems

    Wscript.Echo "Device ID: " & objItem.DeviceID

    Wscript.Echo "Device Name: " & objItem.DeviceName

    dtmWMIDate = objItem.DriverDate

    strReturn = WMIDateStringToDate(dtmWMIDate)

    Wscript.Echo "Driver Date: " & strReturn

    Wscript.Echo "Driver Version: " & objItem.DriverVersion

    Wscript.Echo "Is Signed: " & objItem.IsSigned

    Wscript.Echo

Next

 

Function WMIDateStringToDate(dtmWMIDate)

    If Not IsNull(dtmWMIDate) Then

        WMIDateStringToDate = CDate(Mid(dtmWMIDate, 5, 2) & "/" & _

            Mid(dtmWMIDate, 7, 2) & "/" & Left(dtmWMIDate, 4) _

                & " " & Mid (dtmWMIDate, 9, 2) & ":" & _

                    Mid(dtmWMIDate, 11, 2) & ":" & Mid(dtmWMIDate,13, 2))

    End If

End Function

别因为代码而踯躅不前。此脚本有点让人望而生畏（尤其是末尾部分），但那是因为我们使用了小傻瓜函数，我们不得不使用该函数将 WMI 的 UTC 日期时间值（如 20010701000000.******+***）转换成更为易读的日期时间值（如 7/1/2001）。今天我们不打算详述此函数的原理；如果您想了解更多关于我们在此要所做的事情（以及我们如何着手工作），请查看 Microsoft Windows 2000 脚本指南的此部分。我们还应当指出，如果您运行 Windows 2000 或更早的 Windows 版本，此函数是必需的。如果您运行 Windows XP 或 Windows Server 2003，则有略微简单的方法将 UTC 日期转换为实际日期。我们选择使用傻瓜函数是因为它对于任何 Windows 版本都屡试不爽。

噢，糟糕！快，快投篮啊！

嗯，我们将把门关上，这样 CD 播放机就不会再干扰我们了。

是的，他听的音乐不寻常。可能是某种街头说唱音乐。

除了傻瓜日期时间转换程序以外，脚本的其余内容都一目了然。我们首先连接本地计算机上的 WMI 服务；当然 - 让我们一起这么说 - 我们还可以对远程计算机运行此脚本。（怎么办？只需将远程计算机的名称赋给变量 strComputer。）然后，我们用下面这行代码来检索该计算机上所安装的所有即插即用设备驱动程序的集合：

Set colItems = objWMIService.ExecQuery("Select * from Win32_PnPSignedDriver")

然后，我们只设置一个 For Each 循环来遍历该设备驱动程序的集合，从而回显属性（例如 DeviceName 和 DriverVersion）的值。在我们遇到 DriverDate 属性时，出现了棘手的部分（实际上并不那么棘手）。如果我们只是回显 DriverDate，我们将得到一个难看的 UTC 日期时间值。因此，我们不是回显 DriverDate 的值，而是插入以下代码：

dtmWMIDate = objItem.DriverDate

strReturn = WMIDateStringToDate(dtmWMIDate)

Wscript.Echo "Driver Date: " & strReturn

正如您所见，我们取出 DriverDate 的值，将其存储在名为 dtmWMIDate 的变量中。然后，我们调用函数 WMIDateStringToDate（漂亮的名称，对吧？），传递变量 dtmWMIDate ，使其作为函数参数。该函数为我们转换日期并将转换后的值存储在名为 strReturn 的变量中。于是，我们最终回显的是该变量的值（而非实际的属性值）。

咦：他带球走步了。好的：他是不是每次得球后都走步啊？

我们的意思是，哎呀，难道这看起来不是获得设备驱动程序信息的简单方法吗？

无论如何，我们现在必须走了；到了观看威斯康星队击败亚利桑那队的时候了。

我们的意思是，哎呀，一定是到了比平常工作多得多的时候了 …。